***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Feb 23, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt BZT52-B8V2S A K
.param
+vc0 = 4.072e-11	vc1 = 2.024e-11		vc2 = 5.061e-16		vc3 = 2.529e0
+tc1 = 1.562e-2		tc2 = 5.234e-3		tc3 = 8.022e-3		tc4 = 1.034e-2
d1 A K zener
g1 K A value = {(vc0+vc1*v(K,A)^2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc2*exp(vc3*v(K,A)))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
.model zener d
***** flag parameter ***
+level = 1   
***** dc model parameter ***
+ is = 5.068e-15	   n = 1.075		  rs = 5.116e-1		ikf = 1.081e-2
+ibv = 5e-3		 nbv = 0.5		  bv = 8.2
***** capacitance parameter ***
+cjo = 5.601e-10	   m = 3.316e-1		  vj = 5.955e-1
+ fc = 0.5                      
***** temperature coefficient ***
+tnom = 25		  eg = 1.128		 xti = 3
+trs1 = 3.024e-4	trs2 = 2.446e-6		tbv1 = 5.101e-4		tbv2 = 1.675e-7		tikf = 1.012e-2
.ends BZT52-B8V2S
*$
